Delay를 사용하지 않는 NeoPixel 예제 소스

NeoPixel_without_Delay

 

 

#include <Adafruit_NeoPixel.h>
#ifdef __AVR__
  #include <avr/power.h>
#endif
 
#define PIN 6
 
Adafruit_NeoPixel strip = Adafruit_NeoPixel(60, PIN, NEO_GRB + NEO_KHZ800);
 
const int com_num = 9;
int com = 0;
 
long led_count = 0;
unsigned long time_ms;
 
void setup() {
  #if defined (__AVR_ATtiny85__)
    if (F_CPU == 16000000) clock_prescale_set(clock_div_1);
  #endif
 
  strip.begin();
  strip.show(); // Initialize all pixels to 'off'
}
 
void loop() {
  switch(com) {
    case 0:
      colorWipe(strip.Color(255, 0, 0), 50); // Red
      break;
    case 1:
      colorWipe(strip.Color(0, 255, 0), 50); // Green
      break;
    case 2:
      colorWipe(strip.Color(0, 0, 255), 50); // Blue
      break;
    case 3:
      theaterChase(strip.Color(127, 127, 127), 50); // White
      break;
    case 4:
      theaterChase(strip.Color(127, 0, 0), 50); // Red
      break;
    case 5:
      theaterChase(strip.Color(0, 127, 0), 50); // Green
      break;
    case 6:
      theaterChase(strip.Color(0, 0, 127), 50); // Blue
      break;
    case 7:
      rainbow(20);
      break;
    case 8:
      rainbowCycle(20);
      break;
    case 9:
      theaterChaseRainbow(50);
      break;
  }
}
 
// Fill the dots one after the other with a color
void colorWipe(uint32_t c, uint8_t wait) {
  if(millis() > time_ms + wait) {
    time_ms = millis();
    strip.setPixelColor(led_count, c);
    strip.show();
    led_count++;
    if(led_count>=strip.numPixels()) {
      led_count = 0;
      com++;
      if(com > com_num) {
        com = 0;
      }
    }
  }
}
 
void rainbow(uint8_t wait) {
  if(millis() > time_ms + wait) {
    time_ms = millis();
    for(uint16_t i=0; i<strip.numPixels(); i++) {
      strip.setPixelColor(i, Wheel((i+led_count) & 255));
    }
    strip.show();
    led_count++;
    if(led_count>=256) {
      led_count = 0;
      com++;
      if(com > com_num) {
        com = 0;
      }
    }
  }
}
 
// Slightly different, this makes the rainbow equally distributed throughout
void rainbowCycle(uint8_t wait) {
  if(millis() > time_ms + wait) {
    time_ms = millis();
    for(uint16_t i=0; i< strip.numPixels(); i++) {
      strip.setPixelColor(i, Wheel(((i * 256 / strip.numPixels()) + led_count) & 255));
    }
    strip.show();
    led_count++;
    if(led_count>=256*5) {
      led_count = 0;
      com++;
      if(com > com_num) {
        com = 0;
      }
    }
  }
}
 
//Theatre-style crawling lights.
void theaterChase(uint32_t c, uint8_t wait) {
  if(millis() > time_ms + wait) {
    time_ms = millis();
    for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
      strip.setPixelColor(i+(led_count%3), c);    //turn every third pixel on
    }
    strip.show();
    for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
      strip.setPixelColor(i+(led_count%3), 0);        //turn every third pixel off
    }
    led_count++;
    if(led_count>=10*3) {
      led_count = 0;
      com++;
      if(com > com_num) {
        com = 0;
      }
    }
  }
}
 
//Theatre-style crawling lights with rainbow effect
void theaterChaseRainbow(uint8_t wait) {
  if(millis() > time_ms + wait) {
    time_ms = millis();
    for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
      strip.setPixelColor(i+(led_count%3), Wheel( (i+(led_count/3)) % 255));    //turn every third pixel on
    }
    strip.show();
    for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
      strip.setPixelColor(i+(led_count%3), 0);        //turn every third pixel off
    }
    led_count++;
    if(led_count>=256*3) {
      led_count = 0;
      com++;
      if(com > com_num) {
        com = 0;
      }
    }
  }
}
 
uint32_t Wheel(byte WheelPos) {
  WheelPos = 255 - WheelPos;
  if(WheelPos < 85) {
    return strip.Color(255 - WheelPos * 3, 0, WheelPos * 3);
  }
  if(WheelPos < 170) {
    WheelPos -= 85;
    return strip.Color(0, WheelPos * 3, 255 - WheelPos * 3);
  }
  WheelPos -= 170;
  return strip.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
}